// Buckshot (Quake Super Shotgun)

ACTOR BuckShot : IDMWeapon
{
	Weapon.SelectionOrder 800
	Weapon.SlotNumber 3
	Weapon.AmmoType "IDMShell"
	Weapon.AmmoGive 4
	Weapon.AmmoUse 2
	Weapon.Kickback 200
	Weapon.PreferredSkin "SawedOffMarine"
	Inventory.PickupMessage "Buckshot!"
	Obituary "%o ate 2 loads of %k's Buckshot."
	Attacksound "weapons/dbstck"
	Tag "Buckshot"
	Decal Bulletchip
	Damagetype "Bullet"
	+WEAPON.ALLOW_WITH_RESPAWN_INVUL
	+WEAPON.NOLMS
	States
	{
	Spawn:
	  DBMS A -1 Bright
	  Stop
	Ready:
	  DBST A 1 A_WeaponReady
	  Loop
	Deselect:
	  DBST A 0 A_Lower
	  DBST A 0 A_Lower
	  DBST A 1 A_Lower
	  Loop
	Select:
	  TNT1 A 0 A_PlaySound("weapons/wswitch",CHAN_WEAPON)
	Sloop:
	  DBST A 0 A_Raise
	  DBST A 0 A_Raise
	  DBST A 1 A_Raise
	  Loop
	Fire:
	  DBST B 0 A_GunFlash
	  BSTK B 0 A_JumpIfInventory("PowerIDMWeaponLevel2",1,"Level2")
	  BSTK B 0 A_JumpIfInventory("PowerQuadDamage",1,"Quad")
	Normal:
	  DBST A 4 A_Firebullets(5.6,3.55,18,5,"IDMBulletPuff")
	  Goto FireEnd
	Level2:
	  TNT1 A 0 A_JumpIfInventory("PowerQuadDamage", 1, "QuadLevel2")
	  DBST A 2 A_Firebullets(5.6,3.55,18,5,"IDMBulletPuff",FBF_NOFLASH)
	  DBST A 2 A_Firebullets(5.6,3.55,18,5,"IDMBulletPuff")
	  Goto FireEnd
	Quad:
	  TNT1 A 0 A_Playsound("misc/qdmg",CHAN_AUTO,1)
	  DBST A 4 A_Firebullets(5.6,3.55,18,5,"ExtremePuff")
	  Goto FireEnd
	QuadLevel2:
	  TNT1 A 0 A_Playsound("misc/qdmg2",CHAN_5,1)
	  DBST A 2 A_Firebullets(5.6,3.55,18,5,"ExtremePuff",FBF_NOFLASH)
	  TNT1 A 0 A_Playsound("misc/qdmg2",CHAN_5,1)
	  DBST A 2 A_Firebullets(5.6,3.55,18,5,"ExtremePuff")
	FireEnd:
	  DBST B 8
	  DBST C 7
	  DBST A 6
	  DBST A 0 A_Refire
	  Goto Ready
	Flash:
	  DBST D 5 Bright A_Light1
	  Goto LightDone
	}
}